home *** CD-ROM | disk | FTP | other *** search
/ 8bitfiles.net/archives / archives.tar / archives / genie-commodore-file-library / C64-128Toolkit / MSD-DU15.ARC / DISPLAY A CHAIN (.txt) < prev    next >
Encoding:
Commodore BASIC  |  2019-04-13  |  2.0 KB  |  101 lines
  1. 100 POKE53280,11:POKE53281,15
  2. 110 CLR
  3. 115 POKE646,4
  4. 120 PRINTCHR$(147)"        DISPLAY A CHAIN - 1541"
  5. 125 POKE646,0
  6. 130 PRINT"INSERT DISKETTE IN DRIVE"
  7. 140 INPUT"TRACK & SECTOR (T,S)";T,S
  8. 150 IFT<1ORT>35THENEND
  9. 160 NS=20+2*(T>17)+(T>24)+(T>30)
  10. 170 IFS<0ORS>NSTHENEND
  11. 180 INPUT"OUTPUT TO SCREEN OR PRINTER (S/P)  S[157][157][157]";O$
  12. 190 IFO$<>"S"ANDO$<>"P"THENEND
  13. 200 INPUT"ARE YOU SURE  Y[157][157][157]";Q$
  14. 210 IFQ$<>"Y"THENEND
  15. 220 OPEN15,8,15
  16. 230 PRINT#15,"I0"
  17. 240 INPUT#15,EN$,EM$,ET$,ES$
  18. 250 IFEN$="00"GOTO290
  19. 260 PRINT""EN$", "EM$","ET$","ES$
  20. 270 CLOSE15
  21. 280 END
  22. 290 IFO$="S"GOTO390
  23. 300 PRINT"PRINTING[146] A CHAIN"
  24. 310 OPEN4,4
  25. 320 FORI=1TO6
  26. 330 PRINT#4
  27. 340 NEXTI
  28. 350 PRINT#4,"             DISPLAY A CHAIN"
  29. 360 PRINT#4,"         BLOCK   TRACK - SECTOR"
  30. 370 PRINT#4
  31. 380 GOTO420
  32. 390 PRINT"[147]             DISPLAY A CHAIN            [146]"
  33. 400 PRINT"         BLOCK   TRACK - SECTOR         [146]"
  34. 410 PRINT""
  35. 420 B=B+1
  36. 430 GOSUB1030
  37. 450 JOB=176
  38. 460 GOSUB910
  39. 470 IFE<>1GOTO520
  40. 490 JOB=128
  41. 500 GOSUB910
  42. 510 IFE=1GOTO630
  43. 520 IFE>1ANDE<12THENEN$=RIGHT$(STR$(E+18),2):GOTO540
  44. 530 EN$="02":EM$="?TIMEOUT":GOTO550
  45. 540 EM$="READ ERROR"
  46. 550 ET$=T$
  47. 560 ES$=S$
  48. 570 IFO$="P"THENPRINT#4,"          "EN$", "EM$","ET$","ES$:GOTO590
  49. 580 PRINT"          "EN$", "EM$","ET$","ES$
  50. 590 IFE=4ORE=5GOTO630
  51. 600 IFO$="P"GOTO810
  52. 610 GOSUB1090
  53. 620 GOTO820
  54. 630 B$=RIGHT$(STR$(B),LEN(STR$(B))-1)
  55. 640 IFB<10THENB$=" "+B$
  56. 650 IFB<100THENB$=" "+B$
  57. 660 IFO$="P"THENPRINT#4,"          "B$"       "T$" - "S$:GOTO680
  58. 670 PRINT"          "B$"       "T$" - "S$
  59. 680 PRINT#15,"M-R"CHR$(0)CHR$(4)CHR$(2)
  60. 690 GET#15,T$
  61. 700 T=ASC(T$+CHR$(0))
  62. 710 IFT=0GOTO760
  63. 720 GET#15,S$
  64. 730 S=ASC(S$+CHR$(0))
  65. 740 IFT>35ORS>20+2*(T>17)+(T>24)+(T>30)GOTO850
  66. 750 IFO$="S"ANDB/16<>INT(B/16)GOTO420
  67. 760 IFO$="P"GOTO780
  68. 770 GOSUB1090
  69. 780 IFT=0GOTO810
  70. 790 IFO$="S"GOTO390
  71. 800 GOTO420
  72. 810 IFO$="P"THENCLOSE4
  73. 820 CLOSE15
  74. 830 GOTO110
  75. 840 REM ILLEGAL TRACK OR SECTOR
  76. 850 GOSUB1030
  77. 860 IFO$="P"THENPRINT#4,"         66, ILLEGAL TRACK OR SECTOR,"T$","S$:GOTO810
  78. 870 PRINT"66, ILLEGAL TRACK OR SECTOR,"T$","S$
  79. 880 GOSUB1090
  80. 890 GOTO820
  81. 910 TRY=0
  82. 920 PRINT#15,"M-W"CHR$(8)CHR$(0)CHR$(2)CHR$(T)CHR$(S)
  83. 930 PRINT#15,"M-W"CHR$(1)CHR$(0)CHR$(1)CHR$(JOB)
  84. 940 TRY=TRY+1
  85. 950 PRINT#15,"M-R"CHR$(1)CHR$(0)
  86. 960 GET#15,E$
  87. 970 IFE$=""THENE$=CHR$(0)
  88. 980 E=ASC(E$)
  89. 990 IFTRY=500GOTO1010
  90. 1000 IFE>127GOTO940
  91. 1010 RETURN
  92. 1030 T$=RIGHT$(STR$(T),LEN(STR$(T))-1)
  93. 1040 IFT<10THENT$="0"+T$
  94. 1050 S$=RIGHT$(STR$(S),LEN(STR$(S))-1)
  95. 1060 IFS<10THENS$="0"+S$
  96. 1070 RETURN
  97. 1090 PRINT"PRESS RETURN[146] TO CONTINUE"
  98. 1100 GETC$:IFC$=""THEN1100
  99. 1110 IFC$<>CHR$(13)GOTO1100
  100. 1120 RETURN
  101.